Cannot locate HOWTO_FeCMn file

[KaylaOsterberg]

Hello,

I am having trouble finding the HOWTO_FeCMn TCM file. I have checked through the example documentation and downloads, but I still cannot find it. Could anyone kindly link it for me?

Thank you.

[Bernd]

Hi KaylaOsterberg,

Welcome to the MICRESS Forum.

You can find this file in the directory of the training examples within your installation (..\MICRESS-7.300\Examples\Training). There is nothing special with it, you can also use any of the .TCM macro files as a template which come with each .GES5-file within the GES_Files directories. The content of HOWTO_FeCMn TCM is like that:


@@ to record a log file in interactive mode use: set_log_file <filename>
@@ to stop recording, just exit tcs
@@
@@ lets see what we are doing:
set-echo
@@
@@select thermodynamic database
@@ GOTO_MODULE DATABASE_RETRIEVAL
goto dat
@@
@@for example TCFe6 iron and steel database
@@ SWITCH_DATABASE TCFE6
sw TCFe6
@@
@@which list the database elements
@@ LIST_DATABASE elements
l-d elements
@@
@@define elements in alloy systems
@@ DEFINE_SYSTEM fe c mn
d-sys fe c mn
@@
@@list the system
@@ LIST_SYSTEM CONSTITUENT
l-sy CONSTITUENT
@@ LIST_SYSTEM phases
l-sy phases
@@
@@define phases of interest
@@first reject all phases
@@ REJECT phases *
rej phases *
@@
@@then restore phases of interest
@@e.g. fcc liquid and bcc
@@ RESTORE phases liq fcc bcc
@@
rest phases liq fcc bcc
@@
@@get defined system into Ges Workspace
@@ GET_DATA
get
@@
@@Optional: Append mobility database
@@
@@ Useful combinations of mobility and thermodynamic databases
@@ mobFE1 SSOL
@@ mobAL1 TTAL (COST)
@@ mobAL2 TCAL
@@ mobNI1 TTNI
@@ mobNI2 TCNI
@@
@@ APPEND_DATABASE mob2
app mob2
@@
@@define elements in alloy systems (same as above!!)
@@ DEFINE_SYSTEM fe c mn
d-sys fe c mn
@@
@@list the system
@@ LIST_SYSTEM CONSTITUENT
l-sy CONSTITUENT
@@ LIST_SYSTEM phases
l-sy phases
@@
@@define phases of interest
@@first reject all phases
@@ REJECT phases *
rej phases *
@@
@@then restore phases of interest for diffusion
@@(and modelled in database!)e.g. fcc and bcc:
@@ RESTORE phases fcc bcc
rest phases fcc bcc
@@
@@get defined/appended system into Ges Workspace
@@ GET_DATA
get
@@
@@goto Gibbs Workspace
@@ GOTO_MODULE GIBBS_ENERGY_SYSTEM
go gibbs
@@
@@save Gibbs Workspace to file (here: FeCMn.ges)
@@ SAVE_GES_WORKSPACE
save FeCMn
@@


Best wishes
Bernd